vlowres
Prev | Orchestra Opcodes and Operators | Next

## vlowres

vlowres — A bank of filters in which the cutoff frequency can be separated under user control.

## Description

A bank of filters in which the cutoff frequency can be separated under user control

## Syntax

    ares vlowres asig, kfco, kres, iord, ksep

## Initialization

iord -- total number of filters (1 to 10)

## Performance

asig -- input signal

kfco -- frequency cutoff (not in Hz)

ksep -- frequency cutoff separation for each filter

vlowres (variable resonant lowpass filter) allows a variable response curve in resonant filters. It can be thought of as a bank of lowpass resonant filters, each with the same resonance, serially connected. The frequency cutoff of each filter can vary with the kcfo and ksep parameters.

## Examples

Here is an example of the vlowres opcode. It uses the file vlowres.csd, and beats.wav.

Example 547. Example of the vlowres opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    -odac           -iadc     -d     ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o vlowres.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 44100
    kr = 4410
    ksmps = 10
    nchnls = 1

    ; Instrument #1.
    instr 1
      ; Use a nice sawtooth waveform.
      asig vco 32000, 220, 1

      ; Vary the cutoff frequency from 30 to 300 Hz.
      kfco line 30, p3, 300
      kres = 25
      iord = 2
      ksep = 20

      ; Apply the filters.
      avlr vlowres asig, kfco, kres, iord, ksep

      ; It gets loud, so clip the output amplitude to 30,000.
      a1 clip avlr, 1, 30000
      out a1
    endin

    </CsInstruments>
    <CsScore>

    ; Table #1, a sine wave.
    f 1 0 16384 10 1

    ; Play Instrument #1 for two seconds.
    i 1 0 2
    e

    </CsScore>
    </CsoundSynthesizer>

## Credits

Author: Gabriel Maldonado
Italy

Example written by Kevin Conder.

New in Csound version 3.49

Prev | Up | Next
vlinseg | Home | vmap