fmpercfl
Prev | Orchestra Opcodes and Operators | Next

## fmpercfl

fmpercfl — Uses FM synthesis to create a percussive flute sound.

## Description

Uses FM synthesis to create a percussive flute sound. It comes from a family of FM sounds, all using 4 basic oscillators and various architectures, as used in the TX81Z synthesizer.

## Syntax

    ares fmpercfl kamp, kfreq, kc1, kc2, kvdepth, kvrate, ifn1, ifn2, \
          ifn3, ifn4, ivfn

## Initialization

All these opcodes take 5 tables for initialization. The first 4 are the basic inputs and the last is the low frequency oscillator (LFO) used for vibrato. The last table should usually be a sine wave.

The initial waves should be:

- ifn1 -- sine wave

- ifn2 -- sine wave

- ifn3 -- sine wave

- ifn4 -- sine wave

## Performance

kamp -- Amplitude of note.

kfreq -- Frequency of note played.

kc1, kc2 -- Controls for the synthesizer:

- kc1 -- Total mod index

- kc2 -- Crossfade of two modulators

- Algorithm -- 4

kvdepth -- Vibrator depth

kvrate -- Vibrator rate

## Examples

Here is an example of the fmpercfl opcode. It uses the file fmpercfl.csd.

Example 186. Example of the fmpercfl opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    -odac           -iadc     -d     ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o fmpercfl.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 44100
    kr = 4410
    ksmps = 10
    nchnls = 1

    ; Instrument #1.
    instr 1
      kamp = 30000
      kfreq = 220
      kc1 = 5
      kc2 = 5
      kvdepth = 0.005
      kvrate = 6
      ifn1 = 1
      ifn2 = 1
      ifn3 = 1
      ifn4 = 1
      ivfn = 1

      a1 fmpercfl kamp, kfreq, kc1, kc2, kvdepth, kvrate, ifn1, ifn2, ifn3, ifn4, ivfn
      out a1
    endin

    </CsInstruments>
    <CsScore>

    ; Table #1, a sine wave.
    f 1 0 32768 10 1

    ; Play Instrument #1 for one second.
    i 1 0 1
    e

    </CsScore>
    </CsoundSynthesizer>

## See Also

fmb3, fmbell, fmmetal, fmrhode, fmwurlie

## Credits

Author: John ffitch (after Perry Cook)
University of Bath, Codemist Ltd.
Bath, UK

Example written by Kevin Conder.

New in Csound version 3.47

Prev | Up | Next
fmmetal | Home | fmrhode