rezzy
Prev | Orchestra Opcodes and Operators | Next

## rezzy

rezzy — A resonant low-pass filter.

## Description

A resonant low-pass filter.

## Syntax

    ares rezzy asig, xfco, xres [, imode, iskip]

## Initialization

imode (optional, default=0) -- high-pass or low-pass mode. If zero, rezzy is low-pass. If not zero, rezzy is high-pass. Default value is 0. (New in Csound version 3.50) iskip (optional, default=0) -- if non zero skip the initialisation of the filter. (New in Csound version 4.23f13 and 5.0)

## Performance

asig -- input signal

xfco -- filter cut-off frequency in Hz. As of version 3.50, may i-,k-, or a-rate.

xres -- amount of resonance. Values of 1 to 100 are typical. Resonance should be one or greater. As of version 3.50, may a-rate, i-rate, or k-rate.

rezzy is a resonant low-pass filter created empirically by Hans Mikelson.

## Examples

Here is an example of the rezzy opcode. It uses the file rezzy.csd.

Example 441. Example of the rezzy opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    -odac           -iadc     -d     ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o rezzy.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 44100
    kr = 4410
    ksmps = 10
    nchnls = 1

    ; Instrument #1.
    instr 1
      ; Use a nice sawtooth waveform.
      asig vco 32000, 220, 1

      ; Vary the filter-cutoff frequency from .2 to 2 KHz.
      kfco line 200, p3, 2000

      ; Set the resonance amount.
      kres init 25

      a1 rezzy asig, kfco, kres

      out a1
    endin

    </CsInstruments>
    <CsScore>

    ; Table #1, a sine wave for the vco opcode.
    f 1 0 16384 10 1

    ; Play Instrument #1 for three seconds.
    i 1 0 3
    e

    </CsScore>
    </CsoundSynthesizer>

## See Also

biquad, moogvcf

## Credits

Author: Hans Mikelson
October 1998

Example written by Kevin Conder.

New in Csound version 3.49

Prev | Up | Next
rewindscore | Home | rigoto