aresonk
Prev | Orchestra Opcodes and Operators | Next

## aresonk

aresonk — A notch filter whose transfer functions are the complements of the reson opcode.

## Description

A notch filter whose transfer functions are the complements of the reson opcode.

## Syntax

    kres aresonk ksig, kcf, kbw [, iscl] [, iskip]

## Initialization

iscl (optional, default=0) -- coded scaling factor for resonators. A value of 1 signifies a peak response factor of 1, i.e. all frequencies other than kcf are attenuated in accordance with the (normalized) response curve. A value of 2 raises the response factor so that its overall RMS value equals 1. (This intended equalization of input and output power assumes all frequencies are physically present; hence it is most applicable to white noise.) A zero value signifies no scaling of the signal, leaving that to some later adjustment (see balance). The default value is 0.

iskip (optional, default=0) -- initial disposition of internal data space. Since filtering incorporates a feedback loop of previous output, the initial status of the storage space used is significant. A zero value will clear the space; a non-zero value will allow previous information to remain. The default value is 0.

## Performance

kres -- the output signal at control-rate.

ksig -- the input signal at control-rate.

kcf -- the center frequency of the filter, or frequency position of the peak response.

kbw -- bandwidth of the filter (the Hz difference between the upper and lower half-power points).

aresonk is a filter whose transfer functions is the complement of resonk. Thus aresonk is a notch filter whose transfer functions represents the “filtered out” aspects of their complements. However, power scaling is not normalized in aresonk but remains the true complement of the corresponding unit.

## Examples

Here is an example of the aresonk opcode. It uses the file aresonk.csd.

Example 48. Example of the aresonk opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;RT audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o aresonk.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>
    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs = 1

    gisin ftgen 0, 0, 2^10, 10, 1

    instr 1

    ksig	randomh	400, 1800, 150
    aout	poscil	.2, 1000+ksig, gisin
    	outs	aout, aout
    endin

    instr 2

    ksig	randomh	400, 1800, 150
    kbw	line	1, p3, 600	; vary bandwith
    ksig	aresonk	ksig, 800, kbw
    aout	poscil	.2, 1000+ksig, gisin
    	outs	aout, aout
    endin

    </CsInstruments>
    <CsScore>
    i 1 0 5
    i 2 5.5 5
    e
    </CsScore>
    </CsoundSynthesizer>

## See Also

areson, atone, atonek, port, portk, reson, resonk, tone, tonek

Prev | Up | Next
areson | Home | atone