oscil3
Prev | Orchestra Opcodes and Operators | Next

## oscil3

oscil3 — A simple oscillator with cubic interpolation.

## Description

oscil3 reads table ifn sequentially and repeatedly at a frequency xcps. The amplitude is scaled by xamp. Cubic interpolation is applied for table look up from internal phase values.

## Syntax

    ares oscil3 xamp, xcps, ifn [, iphs]

    kres oscil3 kamp, kcps, ifn [, iphs]

## Initialization

ifn -- function table number. Requires a wrap-around guard point.

iphs (optional) -- initial phase of sampling, expressed as a fraction of a cycle (0 to 1). A negative value will cause phase initialization to be skipped. The default value is 0.

## Performance

kamp, xamp -- amplitude

kcps, xcps -- frequency in cycles per second.

oscil3 is identical to oscili, except that it uses cubic interpolation.

Table ifn is incrementally sampled modulo the table length and the value obtained is multiplied by amp.

If you need to change the oscillator table with a k-rate signal, you can use oscilikt.

## Examples

Here is an example of the oscil3 opcode. It uses the file oscil3.csd.

Example 404. Example of the oscil3 opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    -odac           -iadc     -d     ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o oscil3.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 44100
    kr = 4410
    ksmps = 10
    nchnls = 1

    ; Instrument #1 - a basic oscillator.
    instr 1
      kamp = 10000
      kcps = 220
      ifn = 1

      a1 oscil kamp, kcps, ifn
      out a1
    endin

    ; Instrument #2 - the basic oscillator with cubic interpolation.
    instr 2
      kamp = 10000
      kcps = 220
      ifn = 1

      a1 oscil3 kamp, kcps, ifn
      out a1
    endin

    </CsInstruments>
    <CsScore>

    ; Table #1, a sine wave table with a small amount of data.
    f 1 0 32 10 0 1

    ; Play Instrument #1, the basic oscillator, for
    ; two seconds. This should sound relatively rough.
    i 1 0 2

    ; Play Instrument #2, the cubic interpolated oscillator, for
    ; two seconds. This should sound relatively smooth.
    i 2 2 2
    e

    </CsScore>
    </CsoundSynthesizer>

## See Also

oscil, oscili, oscilikt

## Credits

Author: John ffitch

Example written by Kevin Conder.

New in Csound version 3.50

Prev | Up | Next
oscil1i | Home | oscili