oscil
Prev | Orchestra Opcodes and Operators | Next

## oscil

oscil — A simple oscillator.

## Description

oscil reads table ifn sequentially and repeatedly at a frequency xcps. The amplitude is scaled by xamp.

## Syntax

    ares oscil xamp, xcps, ifn [, iphs]

    kres oscil kamp, kcps, ifn [, iphs]

## Initialization

ifn -- function table number. Requires a wrap-around guard point.

iphs (optional, default=0) -- initial phase of sampling, expressed as a fraction of a cycle (0 to 1). A negative value will cause phase initialization to be skipped. The default value is 0.

## Performance

kamp, xamp -- amplitude

kcps, xcps -- frequency in cycles per second.

The oscil opcode generates periodic control (or audio) signals consisting of the value of kamp (xamp) times the value returned from control rate (audio rate) sampling of a stored function table. The internal phase is simultaneously advanced in accordance with the kcps or xcps input value.

Table ifn is incrementally sampled modulo the table length and the value obtained is multiplied by amp.

If you need to change the oscillator table with a k-rate signal, you can use oscilikt.

## Examples

Here is an example of the oscil opcode. It uses the file oscil.csd.

Example 403. Example of the oscil opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    -odac           -iadc     -d     ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o oscil.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 44100
    ksmps = 10
    nchnls = 2

    ; Instrument #1 - a basic oscillator.
    instr 1
      kamp = 10000
      kcps = 440
      ifn = p4

    asig	oscil	kamp, kcps, ifn
    	outs	asig,asig
    endin

    </CsInstruments>
    <CsScore>

    ; Table #1, a sine wave.
    f 1 0 16384 10 1
    ; Table #2, a sawtooth wave
    f 2 0 256 7 -1 256 1

    i 1 0 2 1
    i 1 + 2 2
    e

    </CsScore>
    </CsoundSynthesizer>

## See Also

oscili, oscilikt, oscil3, poscil, poscil3

Prev | Up | Next
oscbnk | Home | oscil1