jitter
Prev | Orchestra Opcodes and Operators | Next

## jitter

jitter — Generates a segmented line whose segments are randomly generated.

## Description

Generates a segmented line whose segments are randomly generated.

## Syntax

    kout jitter kamp, kcpsMin, kcpsMax

## Performance

kamp -- Amplitude of jitter deviation

kcpsMin -- Minimum speed of random frequency variations (expressed in cps)

kcpsMax -- Maximum speed of random frequency variations (expressed in cps)

jitter generates a segmented line whose segments are randomly generated inside the +kamp and -kamp interval. Duration of each segment is a random value generated according to kcpsmin and kcpsmax values.

jitter can be used to make more natural and “analog-sounding” some static, dull sound. For best results, it is suggested to keep its amplitude moderate.

## Examples

Here is an example of the jitter opcode. It uses the file jitter.csd.

Example 328. Example of the jitter opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    -odac           -iadc     -d     ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o jitter.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 44100
    kr = 4410
    ksmps = 10
    nchnls = 2

    ; Instrument #1 -- plain instrument.
    instr 1
      aplain vco 20000, 220, 2, 0.83

      outs aplain, aplain
    endin

    ; Instrument #2 -- instrument with jitter.
    instr 2
      ; Create a signal modulated the jitter opcode.
      kamp init 2
      kcpsmin init 4
      kcpsmax init 6
      kj jitter kamp, kcpsmin, kcpsmax

      aplain vco 20000, 220, 2, 0.83
      ajitter vco 20000, 220+kj, 2, 0.83

      outs aplain, ajitter
    endin

    </CsInstruments>
    <CsScore>

    ; Table #1, a sine wave.
    f 1 0 16384 10 1

    ; Play Instrument #1 for 3 seconds.
    i 1 0 3
    ; Play Instrument #2 for 3 seconds.
    i 2 3 3
    e

    </CsScore>
    </CsoundSynthesizer>

## See Also

jitter2, vibr, vibrato

## Credits

Author: Gabriel Maldonado

Example written by Kevin Conder.

New in Version 4.15

Prev | Up | Next
jacktransport | Home | jitter2