STKBowed
Prev | Orchestra Opcodes and Operators | Next

## STKBowed

STKBowed — STKBowed is a bowed string instrument.

## Description

STKBowed is a bowed string instrument, using a waveguide model.

## Syntax

    asignal STKBowed ifrequency, iamplitude, [kc1, kv1[, kc2, kv2[, kc3, kv3[, kc4, kv4[, kc5, kv5]]]]]

## Initialization

ifrequency -- Frequency of note played, in Hertz.

iamplitude -- Amplitude of note played (range 0-1).

## Performance

kc1, kv1, kc2, kv2, kc3, kv3, kc4, kv4, kc5, kv5, kc6, kv6, kc7, kv7, kc8, kv8 -- Up to 8 optional k-rate controller pairs for the STK opcodes. Each controller pair consists of a controller number (kc) followed by a controller value (kv). The 5 controller numbers and values that work for STKBowed are:

- kc, kv -- 2, bow pressure.

- kc, kv -- 4, position on bow.

- kc, kv -- 11, speed of low-frequency oscillator.

- kc, kv -- 1, depth of low-frequency oscillator.

- kc, kv -- 128, volume.

| Note
The code for this opcode is taken directly from the Bowed class in the Synthesis Toolkit in C++ by Perry R. Cook and Gary P. Scavone. More on the STK classes can be found here: https://ccrma.stanford.edu/software/stk/classes.html

## Examples

Here is an example of the STKBowed opcode. It uses the file STKBowed.csd.

Example 768. Example of the STKBowed opcode.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;RT audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o STKBowed.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs = 1

    instr 1

    ipch	= p4
    kpos	= p7
    kpres	line	p5, p3, p6
    kvib	line	0, p3, 7

    asig	STKBowed cpspch(ipch), 1, 2, kpres, 4, kpos, 11, 40, 1, kvib, 128, 100
    asig	=	asig*4			;amplify
    	outs	asig, asig
    endin

    </CsInstruments>
    <CsScore>

    i 1 0 5 6.00 20 100 127
    i 1 + 3 7.00 120 0 0
    i 1 8 3 7.05 120 0 30
    i 1 8 4 7.03  50 0 0
    e
    </CsScore>
    </CsoundSynthesizer>

## Credits

Author: Michael Gogins (after Perry Cook)
Irreducible Productions
New York, NY

New in Csound version 5.11

Prev | Up | Next
STKBlowHole | Home | STKBrass