+
Prev | Orchestra Opcodes and Operators | Next

## +

+ — Addition operator

## Description

Arithmetic operators perform operations of change-sign (negate), don't-change-sign, logical AND logical OR, add, subtract, multiply and divide. Note that a value or an expression may fall between two of these operators, either of which could take it as its left or right argument, as in

a + b * c.

In such cases three rules apply:

1. * and / bind to their neighbors more strongly than + and −. Thus the above expression is taken as

a + (b * c)

with * taking b and c and then + taking a and b * c.

2. + and − bind more strongly than &&, which in turn is stronger than ||:

a && b - c || d

is taken as

(a && (b - c)) || d

3. When both operators bind equally strongly, the operations are done left to right:

a - b - c

is taken as

(a - b) - c

Parentheses may be used as above to force particular groupings.

## Syntax

    +a  (no rate restriction)

    a + b  (no rate restriction)

where the arguments a and b may be further expressions.

## Examples

Here is an example of the + operator. It uses the file adds.csd.

Example 23. Example of the + operator.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;RT audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o adds.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs = 1

    instr 1
    ; add unipolar square to oscil
    kamp = p4
    kcps = 1
    itype = 3

    klfo	lfo kamp, kcps, itype
    printk2	klfo
    asig	oscil 0.7, 440+klfo, 1
    	outs asig, asig

    endin

    </CsInstruments>
    <CsScore>
    ;sine wave.
    f 1 0 32768 10 1

    i 1 0 2 1	;adds 1 Hz to frequency
    i 1 + 2 10	;adds 10 Hz to frequency
    i 1 + 2 220	;adds 220 Hz to frequency

    e

    </CsScore>
    </CsoundSynthesizer>

## See Also

-, &&, ||, *, /, ^, %

Prev | Up | Next
* | Home | -