STKBlowHole
Prev | Orchestra Opcodes and Operators | Next

## STKBlowHole

STKBlowHole — STK clarinet physical model with one register hole and one tonehole.

## Description

This opcode is based on the clarinet model, with the addition of a two-port register hole and a three-port dynamic tonehole implementation.

In this implementation, the distances between the reed/register hole and tonehole/bell are fixed. As a result, both the tonehole and register hole will have variable influence on the playing frequency, which is dependent on the length of the air column. In addition, the highest playing freqeuency is limited by these fixed lengths.

## Syntax

    asignal STKBlowHole ifrequency, iamplitude, [kc1, kv1[, kc2, kv2[, kc3, kv3[, kc4, kv4[, kc5, kv5]]]]]

## Initialization

ifrequency -- Frequency of note played, in Hertz.

iamplitude -- Amplitude of note played (range 0-1).

## Performance

kc1, kv1, kc2, kv2, kc3, kv3, kc4, kv4, kc5, kv5, kc6, kv6, kc7, kv7, kc8, kv8 -- Up to 8 optional k-rate controller pairs for the STK opcodes. Each controller pair consists of a controller number (kc) followed by a controller value (kv). The 5 controller numbers and values that work for STKBlowHole are:

- kc, kv -- 2, stiffness of reed.

- kc, kv -- 4, gain of noise.

- kc, kv -- 11, state of tonehole.

- kc, kv -- 1, state of register.

- kc, kv -- 128, breath pressure.

| Note
The code for this opcode is taken directly from the BlowHole class in the Synthesis Toolkit in C++ by Perry R. Cook and Gary P. Scavone. More on the STK classes can be found here: https://ccrma.stanford.edu/software/stk/classes.html

## Examples

Here is an example of the STKBlowHole opcode. It uses the file STKBlowHole.csd.

Example 768. Example of the STKBlowHole opcode.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;RT audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o STKBlowHole.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs = 1

    instr 1

    ipch	= p4
    kstiff	=	p7
    khole	line	p5, p3, p6

    asig	STKBlowHole	cpspch(ipch), 1, 2, kstiff, 4, 100, 11, khole, 1, 10, 128, 100
    	outs	asig, asig
    endin

    </CsInstruments>
    <CsScore>

    i 1 0 4 10.00 20 127 100
    i 1 + 3 6.09 120  0  10
    e
    </CsScore>
    </CsoundSynthesizer>

## Credits

Author: Michael Gogins (after Perry Cook)
Irreducible Productions
New York, NY

New in Csound version 5.11

Prev | Up | Next
STKBlowBotl | Home | STKBowed