sflooper
Prev | Orchestra Opcodes and Operators | Next

## sflooper

sflooper — Plays a SoundFont2 (SF2) sample preset, generating a stereo sound, with user-defined time-varying crossfade looping.

## Description

Plays a SoundFont2 (SF2) sample preset, generating a stereo sound, similarly to sfplay. Unlike that opcode, though, it ignores the looping points set in the SF2 file and substitutes them for a user-defined crossfade loop. It is a cross between sfplay and flooper2.

## Syntax

    ar1, ar2 sflooper ivel, inotenum, kamp, kpitch, ipreindex, kloopstart, kloopend, kcrossfade \
          [, istart, imode, ifenv, iskip]

## Initialization

ivel -- velocity value

inotenum -- MIDI note number value

ipreindex -- preset index

istart -- playback start pos in seconds

imode -- loop modes: 0 forward, 1 backward, 2 back-and-forth [def: 0]

ifenv -- if non-zero, crossfade envelope shape table number. The default, 0, sets the crossfade to linear.

iskip -- if 1, the opcode initialisation is skipped, for tied notes, performance continues from the position in the loop where the previous note stopped. The default, 0, does not skip initialisation

## Performance

kamp -- amplitude scaling

kpitch -- pitch control (transposition ratio); negative values are not allowed.

kloopstart -- loop start point (secs). Note that although k-rate, loop parameters such as this are only updated once per loop cycle. If loop start is set beyond the end of the sample, no looping will result.

kloopend -- loop end point (secs), updated once per loop cycle.

kcrossfade -- crossfade length (secs), updated once per loop cycle and limited to loop length.

sflooper plays a preset, generating a stereo sound.

These opcodes only support the sample structure of SF2 files. The modulator structure of the SoundFont2 format is not supported in Csound. Any modulation or processing to the sample data is left to the Csound user, bypassing all restrictions forced by the SF2 standard.

Note: The looping points are set on the root key of every sample that is part of the preset of the soundfont. For instance, a soundfont can have a single sample for the whole keyboard. In that case, sflooper will work like flooper and flooper2, because as the sample is transposed, played back at different rates, the loop will get short or longer. If however the soundfont has a sample for each key, than there will be no transposition and the loop will stay the same length (unless you change kpitch).

## Examples

Here is an example of the sflooper opcode. It uses the file sflooper.csd.

Example 733. Example of the sflooper opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in    No messages
    -odac -+rtmidi=virtual  -M0     ;;;realtime audio in, midi in
    ; For Non-realtime ouput leave only the line below:
    ; -o sflooper.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    isf   sfload "07AcousticGuitar.sf2"
          sfpassign 0, isf

    instr 1	; play from score and midi keyboard

          mididefault   60, p3
          midinoteonkey p4, p5
    inum  init p4
    ivel  init p5
    print ivel

    ivel  init    ivel/127		;velocity dependent
    kamp  linsegr 1,1,1,.1,0	;envelope
    kamp  = kamp * .0002		;scale amplitude (= kamp/5000)
    kfreq init 1			;do not change freq from sf
    ;"07AcousticGuitar.sf2" contains 2 samples, on notes E1 and C#4
    ;start loop from beginning, loop .2 seconds - on the root key of these samples
    aL,aR sflooper ivel, inum, kamp*ivel, kfreq, 0, 0, .2, .05
          outs aL, aR

    endin
    </CsInstruments>
    <CsScore>
    f0  60		; stay active for 1 minute

    i1 0 1 60 100
    i1 + 1 62 <
    i1 + 1 65 <
    i1 + 1 69 10
    e
    </CsScore>
    </CsoundSynthesizer>

## See Also

sfilist, sfinstr, sfinstrm, sfload, sfpassign, sfplaym, sfplist, sfpreset

## Credits

Author: Victor Lazzarini
August 2007

New in Csound Version 5.07

Prev | Up | Next
sfload | Home | sfpassign