//------------------------------------------------------------------------------
actor LostSoul 3006
{
	game Doom
	SpawnID 110
	Health 100
	Radius 16
	Height 56
	Mass 50
	Speed 8
	PainChance 256
	Damage 3
	RenderStyle SoulTrans
	ActiveSound "skull/active"
	AttackSound "skull/melee"
	PainSound "skull/pain"
	DeathSound "skull/death"
	Obituary "$ob_skull"
	Monster
	-CountKill
	+NoGravity
	+Float
	+MissileMore
	+DontFall
	states
	{
	Spawn:
		SKUL AB 10 Bright A_Look
		Loop
	See:
		SKUL AB 6 Bright A_Chase
		Loop
	Missile:
		SKUL C 10 Bright A_FaceTarget
		SKUL D 4 Bright A_SkullAttack
		SKUL CD 4 Bright
		Goto Missile+2
	Pain:
		SKUL E 3 Bright
		SKUL E 3 Bright A_Pain
		Goto See
	Death:
		SKUL F 6 Bright
		SKUL G 6 Bright A_Scream
		SKUL H 6 Bright
		SKUL I 6 Bright A_NoBlocking
		SKUL JK 6
		Stop
	}
}
