//------------------------------------------------------------------------------
actor Cyberdemon 16
{
	game Doom
	SpawnID 114
	Health 4000
	Radius 40
	Height 110
	Mass 1000
	Speed 16
	PainChance 20
	MinMissileChance 160
	SeeSound "cyber/sight"
	ActiveSound "cyber/active"
	PainSound "cyber/pain"
	DeathSound "cyber/death"
	Obituary "$ob_cyborg"
	Monster
	+Boss
	+MissileMore
	+FloorClip
	+NoRadiusDmg
	+DontMorph
	+BossDeath
	states
	{
	Spawn:
		CYBR AB 10 A_Look
		Loop
	See:
		CYBR A 3 A_Hoof
		CYBR ABBCC 3 A_Chase
		CYBR D 3 A_Metal
		CYBR D 3 A_Chase
		Loop
	Missile:
		CYBR E 6 A_FaceTarget
		CYBR F 12 A_CyberAttack
		CYBR E 12 A_FaceTarget
		CYBR F 12 A_CyberAttack
		CYBR E 12 A_FaceTarget
		CYBR F 12 A_CyberAttack
		Goto See
	Pain:
		CYBR G 10 A_Pain
		Goto See
	Death:
		CYBR H 10
		CYBR I 10 A_Scream
		CYBR JKL 10
		CYBR M 10 A_NoBlocking
		CYBR NO 10
		CYBR P 30
		CYBR P -1 A_BossDeath
		Stop
	}
}
