fmb3
Prev | Orchestra Opcodes and Operators | Next

## fmb3

fmb3 — Uses FM synthesis to create a Hammond B3 organ sound.

## Description

Uses FM synthesis to create a Hammond B3 organ sound. It comes from a family of FM sounds, all using 4 basic oscillators and various architectures, as used in the TX81Z synthesizer.

## Syntax

    ares fmb3 kamp, kfreq, kc1, kc2, kvdepth, kvrate, ifn1, ifn2, ifn3, \
          ifn4, ivfn

## Initialization

fmb3 takes 5 tables for initialization. The first 4 are the basic inputs and the last is the low frequency oscillator (LFO) used for vibrato. The last table should usually be a sine wave.

The initial waves should be:

- ifn1 -- sine wave

- ifn2 -- sine wave

- ifn3 -- sine wave

- ifn4 -- sine wave

## Performance

kamp -- Amplitude of note.

kfreq -- Frequency of note played.

kc1, kc2 -- Controls for the synthesizer:

- kc1 -- Total mod index

- kc2 -- Crossfade of two modulators

- Algorithm -- 4

kvdepth -- Vibrator depth

kvrate -- Vibrator rate

## Examples

Here is an example of the fmb3 opcode. It uses the file fmb3.csd.

Example 268. Example of the fmb3 opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;realtime audio out
    ;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o fmb3.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs  = 1

    instr 1

    kfreq = 220
    kc1 = p4
    kc2 = p5
    kvrate = 6

    kvdpth line 0, p3, p6
    asig   fmb3 .4, kfreq, kc1, kc2, kvdpth, kvrate, 1, 1, 1, 1, 1
           outs asig, asig

    endin
    </CsInstruments>
    <CsScore>
    ;sine wave.
    f 1 0 32768 10 1

    i 1 0 2  5  5 0.1
    i 1 3 2 .5 .5 0.01
    e
    </CsScore>
    </CsoundSynthesizer>

## See Also

fmbell, fmmetal, fmpercfl, fmrhode, fmwurlie

## Credits

Author: John ffitch (after Perry Cook)
University of Bath, Codemist Ltd.
Bath, UK

New in Csound version 3.47

Prev | Up | Next
FLxyin | Home | fmbell