STKSaxofony
Prev | Orchestra Opcodes and Operators | Next

## STKSaxofony

STKSaxofony — STKSaxofony is a faux conical bore reed instrument.

## Description

STKSaxofony is a faux conical bore reed instrument. This opcode uses a "hybrid" digital waveguide instrument that can generate a variety of wind-like sounds. It has also been referred to as the "blowed string" model. The waveguide section is essentially that of a string, with one rigid and one lossy termination. The non-linear function is a reed table. The string can be "blown" at any point between the terminations, though just as with strings, it is impossible to excite the system at either end. If the excitation is placed at the string mid-point, the sound is that of a clarinet. At points closer to the "bridge", the sound is closer to that of a saxophone.

## Syntax

    asignal STKSaxofony ifrequency, iamplitude, [kc1, kv1[, kc2, kv2[, kc3, kv3[, kc4, kv4[, kc5, kv5[, kc6, kv6[, kc7, kv7]]]]]]]

## Initialization

ifrequency -- Frequency of note played, in Hertz.

iamplitude -- Amplitude of note played (range 0-1).

## Performance

kc1, kv1, kc2, kv2, kc3, kv3, kc4, kv4, kc5, kv5, kc6, kv6, kc7, kv7, kc8, kv8 -- Up to 8 optional k-rate controller pairs for the STK opcodes. Each controller pair consists of a controller number (kc) followed by a controller value (kv). The 7 controller numbers and values that work for STKSaxofony are:

- kc, kv -- 2, stiffness of reed.

- kc, kv -- 26, reed aperture.

- kc, kv -- 11, blow position.

- kc, kv -- 4, noise gain.

- kc, kv -- 29, speed of low-frequency oscillator.

- kc, kv -- 1, depth of low-frequency oscillator.

- kc, kv -- 128, breath pressure.

| Note
The code for this opcode is taken directly from the Saxofony class in the Synthesis Toolkit in C++ by Perry R. Cook and Gary P. Scavone. More on the STK classes can be found here: https://ccrma.stanford.edu/software/stk/classes.html

## Examples

Here is an example of the STKSaxofony opcode. It uses the file STKSaxofony.csd.

Example 783. Example of the STKSaxofony opcode.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;RT audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o STKSaxofony.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs = 1

    instr 1

    ifreq	=	p4
    kstiff	=	p5					;reed stiffness
    kblw	line	p6, p3, p7				;blow position
    kvib	line	0, p3, 127				;vibrato speed

    asig	STKSaxofony cpspch(p4), 1, 2, kstiff, 4, 100, 26, 70, 11, kblw, 1, kvib, 29, 100
    asig	=	asig * .5				;too loud
    	outs asig, asig
    endin

    </CsInstruments>
    <CsScore>

    i 1 0 3 6.00 30 100 10
    i 1 + . 8.00 30 100 100
    i 1 + . 7.00 90 127 30
    e
    </CsScore>
    </CsoundSynthesizer>

## Credits

Author: Michael Gogins (after Georg Essl)
Irreducible Productions
New York, NY

New in Csound version 5.11

Prev | Up | Next
STKRhodey | Home | STKShakers