ftsave
Prev | Orchestra Opcodes and Operators | Next

## ftsave

ftsave — Save a set of previously-allocated tables to a file.

## Description

Save a set of previously-allocated tables to a file.

## Syntax

    ftsave "filename", iflag, ifn1 [, ifn2] [...]

## Initialization

"filename" -- A quoted string containing the name of the file to save.

iflag -- Type of the file to save. (0 = binary file, Non-zero = text file)

ifn1, ifn2, ... -- Numbers of tables to save.

## Performance

ftsave saves a list of tables to a file. The file's format can be binary or text.

| Warning
The file's format is not compatible with a WAV-file and is not endian-safe.

## Examples

Here is an example of the ftsave opcode. It uses the file ftsave.csd.

Example 307. Example of the ftsave opcode.

See the sections Real-time Audio and Command Line Flags for more information on using command line flags.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    ; Audio out   Audio in
    -odac           -iadc    ;;;RT audio I/O
    ; For Non-realtime ouput leave only the line below:
    ; -o ftsave.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    ; Initialize the global variables.
    sr = 44100
    kr = 4410
    ksmps = 10
    nchnls = 1

    ; Table #1, make a sine wave using the GEN10 routine.
    gitmp1 ftgen 1, 0, 32768, 10, 1
    ; Table #2, create an empty table.
    gitmp2 ftgen 2, 0, 32768, 7, 0, 32768, 0

    ; Instrument #1 - a basic oscillator.
    instr 1
      kamp = 20000
      kcps = 440
      ; Use Table #1.
      ifn = 1

      a1 oscil kamp, kcps, ifn
      out a1
    endin

    ; Instrument #2 - Load Table #1 into Table #2.
    instr 2
      ; Save Table #1 to a file called "table1.ftsave".
      ftsave "table1.ftsave", 0, 1

      ; Load the "table1.ftsave" file into Table #2.
      ftload "table1.ftsave", 0, 2

      kamp = 20000
      kcps = 440
      ; Use Table #2, it should contain Table #1's sine wave now.
      ifn = 2

      a1 oscil kamp, kcps, ifn
      out a1
    endin

    </CsInstruments>
    <CsScore>

    ; Play Instrument #1 for 1 second.
    i 1 0 1
    ; Play Instrument #2 for 1 second.
    i 2 2 1
    e

    </CsScore>
    </CsoundSynthesizer>

## See Also

ftloadk, ftload, ftsavek

## Credits

Author: Gabriel Maldonado

Example written by Kevin Conder.

New in version 4.21

Prev | Up | Next
ftmorf | Home | ftsavek