STKClarinet
Prev | Orchestra Opcodes and Operators | Next

## STKClarinet

STKClarinet — STKClarinet uses a simple clarinet physical model.

## Description

STKClarinet uses a simple clarinet physical model.

## Syntax

    asignal STKClarinet ifrequency, iamplitude, [kc1, kv1[, kc2, kv2[, kc3, kv3[, kc4, kv4[, kc5, kv5]]]]]

## Initialization

ifrequency -- Frequency of note played, in Hertz.

iamplitude -- Amplitude of note played (range 0-1).

## Performance

kc1, kv1, kc2, kv2, kc3, kv3, kc4, kv4, kc5, kv5, kc6, kv6, kc7, kv7, kc8, kv8 -- Up to 8 optional k-rate controller pairs for the STK opcodes. Each controller pair consists of a controller number (kc) followed by a controller value (kv). The 5 controller numbers and values that work for STKClarinet are:

- kc, kv -- 2, reed stiffness.

- kc, kv -- 4, gain of noise.

- kc, kv -- 11, speed of low-frequency oscillator.

- kc, kv -- 1, depth of low-frequency oscillator.

- kc, kv -- 128, breath pressure.

| Note
The code for this opcode is taken directly from the Clarinet class in the Synthesis Toolkit in C++ by Perry R. Cook and Gary P. Scavone. More on the STK classes can be found here: https://ccrma.stanford.edu/software/stk/classes.html

## Examples

Here is an example of the STKClarinet opcode. It uses the file STKClarinet.csd.

Example 771. Example of the STKClarinet opcode.

    <CsoundSynthesizer>
    <CsOptions>
    ; Select audio/midi flags here according to platform
    -odac     ;;;RT audio out
    ;-iadc    ;;;uncomment -iadc if RT audio input is needed too
    ; For Non-realtime ouput leave only the line below:
    ; -o STKclarinet.wav -W ;;; for file output any platform
    </CsOptions>
    <CsInstruments>

    sr = 44100
    ksmps = 32
    nchnls = 2
    0dbfs = 1

    instr 1

    ifrq	=	p4
    kpress	=	p5
    kstiff	line	p6, p3, p7
    asig	STKClarinet cpspch(p4), 1, 2, kstiff, 4, 100, 11, 60, 1, 10, 128, kpress
    	outs asig, asig
    endin

    </CsInstruments>
    <CsScore>

    i 1 0 3  8.00 100 127 10
    i 1 + 10 8.08  80  60 100
    e
    </CsScore>
    </CsoundSynthesizer>

## See Also

STKFlute.

## Credits

Author: Michael Gogins (after Perry Cook)
Irreducible Productions
New York, NY

New in Csound version 5.11

Prev | Up | Next
STKBrass | Home | STKDrummer